// Install script for Albion DEMO English version
// 10th of July 1996
// (c) 1996 Blue Byte Software GmbH


// Set language
SET_LANGUAGE 2

// Load background image
LOAD_BACKGROUND "install.lbm"

// Go to setup if already installed, else go to install
IF_EXISTS setup.ini
	GOTO SetupMainMenu
ELSE
	GOTO InstallMainMenu
ENDIF


// Install main menu
:InstallMainMenu

MENU_START
MENU_ENTRY "Albion DEMO: Installation"
MENU_ENTRY "Install Albion DEMO" InstallGame
MENU_ENTRY "Exit program" ExitInstallFromInstall
MENU_END


// Install the game
:InstallGame

// Select a target drive
SELECT_TARGET_DRIVE 3000 InstallMainMenu

// Select target path
SELECT_TARGET_PATH ALBION

// Confirm installation
ASSERT "Continue installation?" InstallMainMenu

// Change to target directory
CD_TARGET

// Delete everything that may already be here
//DELETE *.*
DELETE DRIVERS
DELETE XLDLIBS

// Create directories
MD SAVES
MD DRIVERS
MD XLDLIBS
MD XLDLIBS\INITIAL
MD XLDLIBS\CURRENT

// Change to source directory
CD_SOURCE

// Inform the user that installation has started
PRINT "Installing the Albion DEMO."

// Copy AIL drivers
INSTALL DRIVERS\*.* DRIVERS\*.*

// Copy initial position
INSTALL XLDLIBS\INITIAL\*.* XLDLIBS\INITIAL\*.*

// Copy palettes
INSTALL XLDLIBS\PALETTE.000 XLDLIBS\PALETTE.000
INSTALL XLDLIBS\PALETTE0.XLD XLDLIBS\PALETTE0.XLD

// Copy stuff
INSTALL ROOT\ALBION.EXE ALBION.EXE
INSTALL ROOT\MAIN.EXE MAIN.EXE
INSTALL ROOT\ALBION.PIF ALBION.PIF
INSTALL ROOT\ALBILOW.BAT ALBILOW.BAT
INSTALL ROOT\ALBION.VMC ALBION.VMC
INSTALL SETUP.EXE SETUP.EXE
INSTALL INSTALL.SCR INSTALL.SCR
INSTALL INSTALL.LBM INSTALL.LBM
INSTALL DOS4GW.EXE DOS4GW.EXE
INSTALL README.TXT README.TXT

// Copy saved game for demo
INSTALL SAVES\SAVE.001 SAVES\SAVE.001

CD_TARGET

// Create and update setup file
CREATE SETUP.INI
UPDATE_INI
WRITE_INI_ENTRY DEMO Y

// Inform the user that installation has been completed successfully
INFO "The Albion DEMO has been installed."

GOTO SetupMainMenu


// Setup main menu
:SetupMainMenu

MENU_START
MENU_ENTRY "Albion DEMO: Setup"
MENU_ENTRY "Configure sound hardware" SetupSound
MENU_ENTRY "Additional information" ReadDoc
MENU_ENTRY "Exit program" ExitInstallFromSetup
MENU_END


:SetupSound
CD DRIVERS
EXECUTE_OWN_SCREEN SETSOUND.EXE
CD ..
GOTO SetupMainMenu


:ReadDoc
TEXT README.TXT
GOTO SetupMainMenu


:ExitInstallFromSetup
INFO "Please start the Albion DEMO from the drive you installed it on. Have fun!"
END

:ExitInstallFromInstall
END

